PiBox » Iron Man

/*******************************************************************************

 * PiBox IoT: ESP8266 controller

 *

 * ESP8266IoT.ino:  Provide RESTful interface to control this device.

 *

 * License: see LICENSE file

 ******************************************************************************

 * Notes:

 * Being a C file (and not Java), please adhere to the 80 character line

 * length standard in this file.

 ******************************************************************************/

#include <ESP8266WiFi.h>

#include <WiFiClient.h>

#include <ESP8266WebServer.h>

#include <ESP8266mDNS.h>

#include <WiFiManager.h>

// This is the web server that accepts inbound messages.

ESP8266WebServer server(80);

// Handle auto-connection

// Globally scoped so API can reset, if necessary.

WiFiManager wifiManager;

// Default WiFi config

String ssid = "Reset";

// const char* ssid = "MuseB";

// const char* password = "6953af02c3";

// Device controls stepper motor with 4 settings.

const String cmds[] = {

    "open",         // Open the controlled device

    "close",        // Close the controlled device

    "half",         // Open the controlled device half

    "quarter",      // Open the controlled device one-quarter

    "reset"         // Reset WiFi configuration - must be protected!

};

/*

 * ========================================================================

 * Command Handlers

 * ========================================================================

 */

/*

 * ========================================================================

 * Name:   reset

 * Prototype:  int reset( void )

 *            

 * Description:

 * Reset WiFi connection, allowing reconfiguration.

 *            

 * Notes:

 * Never returns because it calls ESP.reset().

 * ========================================================================

 */ 

void reset() 

{

    wifiManager.resetSettings();

    delay(3000);

    ESP.reset();

    delay(5000);

}

/*

 * ========================================================================

 * URI handling

 * ========================================================================

 */

/*

 * ========================================================================

 * Name:   validate

 * Prototype:  int validate( String domain, String version, String cmd )

 *            

 * Description:

 * Validate inbound request. 

 *            

 * Input Arguments:

 * String  domain     The domain requested.  

 * String  version    The API version requested.  

 * String  cmd        The command requested.

 *

 * Returns:

 * 1 if the request validates.

 * 0 if the request is invalid.

 * ========================================================================

 */ 

int validate(String domain, String version, String cmd) 

{

    String message;

    int    i;

    // This device is in the IronMan (im) domain.

    if ( !domain.equals("im") )

    {

        message = "Invalid domain: ";

        message += domain;

        Serial.println(message);

        return(0);

    }

    // We support only the first version of the API (so far).

    if ( !version.equals("1") )

    {

        message = "Unsupported version: ";

        message += version;

        Serial.println(message);

        return(0);

    }

    // Run through list of valid commands

    for(i=0; i<4; i++)

    {

        if ( cmd.equals(cmds[i]) )

            return(1);

    }

    message = "Unsupported command: ";

    message += cmd;

    Serial.println(message);

    return(0);

}

/*

 * ========================================================================

 * Name:   handleCommand

 * Prototype:  int handleCommand(  String cmd, String args )

 *            

 * Description:

 * Handle valid commands.  This is where motors are controlled.

 * ========================================================================

 */ 

void handleCommand( String cmd, String args ) 

{

    if ( cmd.equals("reset") )

    {

        // Should validate authorization here, probably.

        reset();

        // Should never get here due to call to ESP.reset() in handler.

        return;

    }

    String message = "Handled command\n\n";

    message  = "Command: ";

    message += cmd;

    message += "\targs: ";

    message += args;

    Serial.println(message);

    server.send(404, "text/plain", message);

}

/*

 * ========================================================================

 * Name:   handleNotFound

 * Prototype:  int handleNotFound( void )

 *            

 * Description:

 * Handle invalid requests.  This sends a text reply, which may not be

 * suitable for the remote caller.

 * ========================================================================

 */ 

void handleNotFound() 

{

    String message = "Invalid command\n\n";

    message += "URI: ";

    message += server.uri();

    message += "\nMethod: ";

    message += (server.method() == HTTP_GET)?"GET":"POST";

    message += "\nArguments: ";

    message += server.args();

    message += "\n";

    for (uint8_t i=0; i<server.args(); i++)

    {

        message += " " + server.argName(i) + ": " + server.arg(i) + "\n";

    }

    server.send(404, "text/plain", message);

}

/*

 * ========================================================================

 * Name:   handleREST

 * Prototype:  int handleREST( void )

 *            

 * Description:

 * Handle all RESTful requests.  This parses out the expected 

 * domain, version and command (with any arguments), validates them and

 * then calls the appropriate command handler.

 *

 * Notes:

 * URI format for this API: /domain/version/cmd/args

 * We don't yet handle GET variables.

 * We don't support PUT or any other HTTP commands.  The command and 

 * it's arguments must exist in the URI only.

 * ========================================================================

 */ 

int handleREST() 

{

    String message;

    String path = server.uri();

    int imIdx   = -1;

    int verIdx  = -1;

    int cmdIdx  = -1;

    String prefix, im, ver, cmd, args;

    prefix = path.substring(0,1);

    if ( !path.startsWith("/") )

    {

        Serial.println("Missing leading /");

        handleNotFound();

        return(1);

    }

    // Get path separator indices

    imIdx = path.indexOf("/", 1);

    if ( imIdx != -1 )

        verIdx = path.indexOf("/", imIdx+1);

    if ( verIdx != -1 )

        cmdIdx = path.indexOf("/", verIdx+1);

    if ( (imIdx == -1) || (verIdx == -1) || (cmdIdx == -1) )

    {

        message = "Missing required REST components: uri = ";

        message += server.uri();

        Serial.println(message);

        handleNotFound();

        return(1);

    }

    // Parse 

    im = path.substring(1,imIdx);

    ver = path.substring(imIdx+1,verIdx);

    cmd = path.substring(verIdx+1,cmdIdx);

    args = path.substring(cmdIdx+1);

    // Test validity of message

    if ( !validate( im, ver, cmd ) )

    {

        handleNotFound();

        return(1);

    }

    // Request is valid.  Handle command.

    handleCommand( cmd, args );

}

// Handle root directory access

void handleRoot() 

{

    server.send(200, "text/plain", "hello from esp8266!");

}

/*

 * ========================================================================

 * Name:   setup

 * Prototype:  void setup( void )

 *            

 * Description:

 * Initialization function; required by Arduino enviroment.

 * This function handles setup of WiFi connections and configures

 * URI handlers for the web server.

 * ========================================================================

 */ 

void configModeCallback(WiFiManager *myWiFiManager)

{

    Serial.println("Entered config mode");

    Serial.println(WiFi.softAPIP());

    //if you used auto generated SSID, print it

    Serial.println(myWiFiManager->getConfigPortalSSID());

}

/*

 * ========================================================================

 * Name:   setup

 * Prototype:  void setup( void )

 *            

 * Description:

 * Initialization function; required by Arduino enviroment.

 * This function handles setup of WiFi connections and configures

 * URI handlers for the web server.

 * ========================================================================

 */ 

void setup(void)

{

    Serial.begin(115200);

    // Artifical wait - to get serial console connected.

    delay(5000);

    // Set callback to be notified when connection to last configured

    // remote AP fails.

    wifiManager.setAPCallback(configModeCallback);

#if 0

    // Use this to reset the board to it's default state.

    // You have to uncomment it, build and upload, run it,

    // Then after the board resets once, comment it out and

    // build/upload again.

    if ( ssid.equals("Reset") )

    {

        ssid = "NoReset";

        reset();

    }

#endif

    // Tries to connect with last known settings.

    // If connection fails, starts an access point with no password

    // and waits for configuration.

    if (!wifiManager.autoConnect("imiot")) 

    {

        Serial.println("Failed connection, we should reset as see if it connects");

        delay(3000);

        ESP.reset();

        delay(5000);

    }

    Serial.println("Connected to AP.");

    // Without WiFiManager, this would do the connection for us.

    // WiFi.begin(ssid, password);

    // Serial.println("");

    // Wait for connection

    // while (WiFi.status() != WL_CONNECTED) 

    // {

    //     delay(500);

    //     Serial.print(".");

    // }

    Serial.println("");

    Serial.print("Connected to ");

    Serial.println(WiFi.SSID());

    Serial.print("IP address: ");

    Serial.println(WiFi.localIP());

    // Do we need this for IoT?

#if 0

    if (MDNS.begin("esp8266")) 

    {

        Serial.println("MDNS responder started");

    }

#endif

    // Setup web server URI handlers

    server.on("/", handleRoot);

    server.onNotFound(handleREST);

    // Sert the web server.

    server.begin();

    Serial.println("HTTP server started");

}

/*

 * ========================================================================

 * Name:   loop

 * Prototype:  void loop( void )

 *            

 * Description:

 * Main loop function; required by Arduino enviroment.

 * This function uses the web server API to spin, waiting for inbound

 * connections.  It then calls the appropriate handlers.

 * ========================================================================

 */ 

void loop(void)

{

    server.handleClient();

}